Competency Questions

CQ#1 – For a given period of time, the number of SMEs awarded

Use cases

· Use Case #1: Transparency and Monitoring

· Use Case #4: Analysing eProcurement procedures

Note

· Modify the dates to get different results.

SPARQL query

PREFIX : <http://data.europa.eu/ePO/ontology#>

PREFIX rov: <http://www.w3.org/ns/regorg#>

PREFIX dcterms: <http://purl.org/dc/terms/>

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

PREFIX epo-rd: <http://data.europa.eu/ePO/referencedata#>

select (count(?Award_Date) as ?NUMBER_OF_AWARDED_SME) where {

                ?Award_Result :hasWinner ?Winner ;

:hasAwardResultDateOfConclusion ?Award_Date .

?Winner :usesEOIndustryClassificationType epo-rd:SME .

    FILTER (?Award_Date > "2015-01-01"^^xsd:dateTime && ?Award_Date < "2018-12-31"^^xsd:dateTime)     

}

Conceptual model

Results of the SPARQL query

CQ#2 – List all the winners, the size of the company and the date of award

Use cases

· Use Case #1: Transparency and Monitoring

· Use Case #4: Analysing eProcurement procedures

SPARQL query

PREFIX : <http://data.europa.eu/ePO/ontology#>

PREFIX rov: <http://www.w3.org/ns/regorg#>

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

select distinct ?Winner_Name ?WinnerSize ?Awarded_Date where {

                ?Award_Result :hasWinner ?Winner ;

:hasAwardResultDateOfConclusion ?Awarded_Date .

    ?Winner :usesEOIndustryClassificationType ?WinnerSize ;

rov:legalName  ?Winner_Name .

}

Conceptual model

Results of the SPARQL query

CQ#3 – The number of contracts awarded for each CPV

Use cases

· Use Case #1: Transparency and Monitoring

· Use Case #4: Analysing eProcurement procedures

SPARQL query

PREFIX : <http://data.europa.eu/ePO/ontology#>

SELECT ?cpv (COUNT(DISTINCT(?contract)) AS ?number_contracts) where {

                ?contract a :Contract;

:hasContractPurpose ?purpose.

    ?purpose :hasCPVType ?cpv.

} group by ?cpv order by desc(?number_contracts)

Conceptual model

Results of the SPARQL query

Other Examples

1. Total of contract award notices

SPARQL query

PREFIX : <http://data.europa.eu/ePO/ontology#>

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

select (count(distinct ?contract_award_notice) as ?Total_Contract_Award_Notices) where {

                ?contract_award_notice rdf:type :ContractAwardNotice ;

:hasDocumentIdentifier ?doc_id.

}

Conceptual model

Results of the SPARQL query

2. Search by awarding authority name

SPARQL query

PREFIX : <http://data.europa.eu/ePO/ontology#>

PREFIX ccts: <http://www.unece.org/cefact#>

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

select distinct ?Document_Reference ?Authority_Name  where {

    ?contracts a :Contract;

               :attachesDocument ?notice;

:refersToSignatoryPartyProcuringEntity ?procuring_entities.

    ?notice :hasDocumentIdentifier ?id.

    ?id ccts:identifierValue ?Document_Reference.

     ?procuring_entities skos:prefLabel ?Authority_Name.

    filter (?Authority_Name = 'City of London Corporation')

} group by ?procuring_entities ?Authority_Name ?Document_Reference

Conceptual model

Results of the SPARQL query

3. Search by procuring entity country

SPARQL query

PREFIX : <http://data.europa.eu/ePO/ontology#>

PREFIX ccts: <http://www.unece.org/cefact#>

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

PREFIX org: <http://www.w3.org/ns/org#>

PREFIX vcard: <http://www.w3.org/2006/vcard/ns#>

PREFIX euvoc: <http://publications.europa.eu/ontology/euvoc#>

select distinct ?Document_Reference  ?country ?publication_date where {

    ?contracts a :Contract;

               :attachesDocument ?notice;

:refersToSignatoryPartyProcuringEntity ?procuring_entities.

    ?notice :hasDocumentIdentifier ?id;

:hasPublicationDate ?publication_date.

    ?id ccts:identifierValue ?Document_Reference .

     ?procuring_entities org:hasSite ?site.

    ?site vcard:hasAddress ?address.

    ?address vcard:country-name ?country

    filter (?country = euvoc:BE)

} group by ?procuring_entities ?country ?Document_Reference  ?publication_date ?description

order by ?Document_Reference

Conceptual model

Results of the SPARQL query

4. Search by the location of the procuring entity

SPARQL query: List notices where the procuring entity is located in “Madrid”.

PREFIX : <http://data.europa.eu/ePO/ontology#>

PREFIX ccts: <http://www.unece.org/cefact#>

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

PREFIX org: <http://www.w3.org/ns/org#>

PREFIX vcard: <http://www.w3.org/2006/vcard/ns#>

PREFIX euvoc: <http://publications.europa.eu/ontology/euvoc#>

select distinct ?Document_Reference ?place ?publication_date where {

    ?contracts a :Contract;

               :attachesDocument ?notice;

:refersToSignatoryPartyProcuringEntity ?procuring_entities.

    ?notice :hasDocumentIdentifier ?id;

:hasPublicationDate ?publication_date.

    ?id ccts:identifierValue ?Document_Reference.

     ?procuring_entities org:hasSite ?site.

    ?site vcard:hasAddress ?address.

    ?address vcard:locality ?place

    filter (?place = "Madrid")

} group by ?procuring_entities ?place ?Document_Reference ?publication_date ?description

order by ?Document_Reference

Conceptual model

Results of the SPARQL query